Init Examples (GNU Emacs Manual (Japanese Translation))

Next: 端末固有の初期化, Previous: initファイルの構文, Up: Emacs初期化ファイル [Contents][Index]

51.4.2 initファイルの例 ¶

以下はLisp式で一般的に行ないたいような事柄の例です:

変数load-pathにディレクトリーを追加します。その後、Emacsに含まれていないLispライブラリーをそのディレクトリーに配置すれば、M-x load-libraryでそれらをロードすることができます。EmacsのためのLispコードによるライブラリーを参照してください。
```
(add-to-list 'load-path "/path/to/lisp/libraries")
```
Cモードで、ポイントが行の途中にある場合、TABが単にタブを挿入するようにします。
```
(setq c-tab-always-indent nil)
```
個の例では、変数の通常の値がt、つまり“true”の変数の値を、nilつまり“false”にしています。
(この設定をオーバーライドしないすべてのバッファーで)検索のデフォルトを、大文字小文字を区別させるようにします。
```
(setq-default case-fold-search nil)
```
これはデフォルト値をセットし、この変数にたいするローカル値(ローカル変数を参照してください)をもたないすべてのバッファーに効果を及ぼします。case-fold-searchをsetqでセットした場合は、カレントバッファーだけに効果があり、それは多分あなたがinitファイルで行ないたいことではないはずです。
Emacsがあなたのメールアドレスを正しく推測できない場合、メールアドレスを指定します。
```
(setq user-mail-address "cheney@torture.gov")
```
Messageモードのような、さまざまなEmacsパッケージは、メールアドレスを知る必要がある場合に、user-mail-addressを参照します。メールヘッダーフィールドを参照してください。
新しいバッファーにたいするデフォルトのモードをTextモードにします。
```
(setq-default major-mode 'text-mode)
```
Textモードに入るコマンドにtext-modeが使用されていることに注意してください。前のシングルクォートはシンボルを定数にしています。そうしない場合、text-modeは変数名として扱われます。
西ヨーロッパのほとんどの言語をサポートするLatin-1文字を、デフォルトにセットアップします。
```
(set-language-environment "Latin-1")
```
グローバルなマイナーモードのLine Numberモードをオフに切り替えます。
```
(line-number-mode 0)
```
Textモードと関連するモードで、自動的にAuto Fillモードをオンに切り替えます(フックを参照してください)。
```
(add-hook 'text-mode-hook 'auto-fill-mode)
```
クリップボード使用時のコーディングシステムを変更します(プロセス間通信にたいするコーディングシステムを参照)。
```
(setopt selection-coding-system 'utf-8)
```
インストールされたfooという名前のライブラリー(実際には標準のEmacsディレクトリーのfoo.elcまたはfoo.elというファイル)をロードします。
```
(load "foo")
```
loadの引数が、‘/’や‘~’で始まらない相対ファイル名の場合、loadはload-pathのディレクトリーを検索します(EmacsのためのLispコードによるライブラリーを参照してください)。
ホームディレクトリーの、コンパイルされたLispファイルfoo.elcをロードします。
```
(load "~/foo.elc")
```
ここでは完全なファイル名が使用されているので、検索は行なわれません。
mypackageという名前のLispライブラリー(たとえばmypackage.elcやmypackage.elというファイル)をロードすることにより、関数myfunctionの定義を探すようEmacsに指示します。
```
(autoload 'myfunction "mypackage" "Do what I say." t)
```
ここで文字列"Do what I say."は、この関数のドキュメント文字列です。これをautoload定義の中で指定することにより、そのパッケージがロードされていなくてもヘルプコマンドで利用可能になります。最後の引数tは、この関数がinteractive(対話的)であることを示します。つまり、この関数はM-x myfunction RETとタイプするか、キーにバインドすることにより、対話的に呼び出すことができます。関数がinteractiveでない場合は、tを省略するか、nilを使用します。
関数make-symbolic-linkを実行するように、キーC-x lをリバインドします(initファイル内でのキーのリバインドを参照してください)。
```
(keymap-global-set "C-x l" 'make-symbolic-link)
```
または
```
(keymap-set global-map "C-x l" 'make-symbolic-link)
```
繰り返しになりますが、シングルクォートはmake-symbolic-linkを変数として値を参照するのではなく、シンボルとして参照するために使用されることに注意してください。
Lispモードだけで、同じことを行ないます。
```
(keymap-set lisp-mode-map "C-x l" 'make-symbolic-link)
```
Fundamentalモードでnext-lineを実行するすべてのキーにたいして、かわりにforward-lineを実行するように再定義します。
```
(keymap-substitute global-map 'next-line 'forward-line)
```
C-x C-vを未定義にします。
```
(keymap-global-unset "C-x C-v")
```
キーを未定義にする1つの理由は、それをプレフィクスにできることです。単にC-x C-v anythingを定義すると、C-x C-vはプレフィクスになりますが、最初に通常のC-x C-vにたいする非プレフィクス定義を開放しなければなりません。
Textモードで‘$’に句読点構文をもたせます。‘$’にたいする文字定数の使い方に注意してください。
```
(modify-syntax-entry ?\$ "." text-mode-syntax-table)
```
確認なしでの、コマンドnarrow-to-regionの使用を有効にします。
```
(put 'narrow-to-region 'disabled nil)
```
さまざまなプラットフォームとEmacsバージョンにたいして、設定を調整します。
ユーザーは通常、すべてのシステムでEmacsが同じように振る舞うことを期待するので、すべてのプラットフォームで同じinitファイルを使用するのが妥当です。しかしEmacsをカスタマイズするのに使用する関数が、他のプラットフォームやEmacsバージョンで利用できないということも発生します。この状況に対処するには、以下のように、ある関数または機能が利用可能かテストする条件文の内部に、カスタマイズを配置します:
```
(if (fboundp 'blink-cursor-mode)
    (blink-cursor-mode 0))

(if (boundp 'coding-category-utf-8)
    (set-coding-priority '(coding-category-utf-8)))
```
関数が定義されていない場合に発生するエラーを、単に無視することもできます。
```
(ignore-errors (set-face-background 'region "grey75"))
```
存在しない変数へのsetqは一般的に無害なので、これらを条件文の中に置く必要はありません。
自動的にパッケージのロードと構成を行うためにはuse-packageを使用します。
```
(use-package hi-lock
  :defer t
  :init (add-hook 'some-hook 'hi-lock-mode)
  :config (use-package my-hi-lock)
  :bind (("M-o l" . highlight-lines-matching-regexp)
         ("M-o r" . highlight-regexp)
         ("M-o w" . highlight-phrase)))
```
これは初めてhi-lockにコマンドか変数が使用された際にhi-lockをロードするとともに、そのロード後に追加でmy-hi-lockパッケージ(hi-lockを更にカスタマイズしたパッケージかもしれない)をロードします。use-packageの機能については、それ自身のマニュアルにおいて完全に文書化されています。use-package User manualを参照してください。